The SPARQL Queries
The SPARQL Queries used to evaluate the ontology.
The metadata of the experiment datasets are used from IDR website
The results of the SPARQL Queries will be found here
Query 1:
What are the input and output variables of an experiment?
SELECT DISTINCT * WHERE
{
?experiment a repr:Experiment .
?experimentStep p-plan:isStepOfPlan ?experiment .
{
?experimentInput p-plan:isInputVarOf ?experimentStep .
?experimentInput rdf:type ?experimentInputType .
OPTIONAL { ?experimentInput repr:name ?experimentInputName } .
}
UNION {
?experimentOutput p-plan:isOutputVarOf ?experimentStep .
?experimentOutput rdf:type ?experimentOutputType .
OPTIONAL { ?experimentOutput repr:name ?experimentOutputName } .
}
}
Query 2:
Which are the methods and standard operating procedures used?
SELECT DISTINCT * WHERE
{
?experiment a repr:Experiment .
?experimentStep p-plan:isStepOfPlan ?experiment ;
repr:usedMethod ?experimentMethod .
}
Query 3:
Which are the files and materials that were used in a particular step?
SELECT DISTINCT * WHERE
{
?experiment a repr:Experiment .
?experimentStep p-plan:isStepOfPlan ?experiment .
{
?experimentMaterial p-plan:isInputVarOf ?experimentStep ;
repr:name ?experimentMaterialName .
}
}
Query 4:
Which are the steps involved in an experiment which used a particular material?
SELECT DISTINCT ?experiment ?experimentStep ?experimentOutput ?value WHERE
{
?experiment a repr:Experiment .
?experimentStep p-plan:isStepOfPlan ?experiment .
OPTIONAL {
?experimentOutput repr:reference ?referencedmaterial .
?referencedmaterial a repr:GeneSymbol .
?referencedmaterial rdf:value ?value FILTER (?value='CDC20')
}
}
Query 5:
What is the complete path taken by a scientist for an experiment?
SELECT DISTINCT * WHERE
{
?experiment a repr:Experiment .
?experiment repr:name "Focused mitotic chromsome condensaton screen using HeLa cells" .
?experimentStep p-plan:isStepOfPlan ?experiment .
?experiment prov:wasAttributedTo ?agent .
?agent repr:hasRole ?role .
OPTIONAL { ?experimentStep p-plan:isPrecededBy ?previousStep } .
{
?experimentInput p-plan:isInputVarOf ?experimentStep .
?experimentInput rdf:type ?experimentInputType .
OPTIONAL { ?experimentInput repr:name ?experimentInputName } .
}
UNION {
?experimentOutput p-plan:isOutputVarOf ?experimentStep .
?experimentOutput rdf:type ?experimentOutputType .
OPTIONAL { ?experimentOutput repr:name ?experimentOutputName } .
OPTIONAL { ?experimentOutput repr:isAvailableAt ?outputUrl } .
OPTIONAL {?experimentOutput repr:reference ?experimentOutputReference .
?experimentOutputReference rdf:value ?experimentOutputReferenceValue
}
}
}
Query 6:
Which are the instruments that are associated with an experiment and their settings when the output was generated?
SELECT DISTINCT * WHERE
{
?image a repr:Image ;
?instrument p-plan:correspondsToVariable ?image .
?instrument_part a :Detector ;
:isPartOf ?instrument .
?instrument_part :hasSetting ?setting .
?setting a :Setting ;
rdfs:label ?SettingName .
OPTIONAL { ?setting prov:value ?SettingValue } .
OPTIONAL {
?instrument_type prov:specializationOf ?instrument_part ;
prov:value ?InstrumentType } .
}
Query 7:
Which are the agents directly or indirectly responsible for an experiment?
SELECT DISTINCT ?experiment ?agent ?agentName ?role ?material WHERE
{
?experiment a repr:Experiment .
?step p-plan:isStepOfPlan ?experiment .
{
?experiment prov:wasAttributedTo ?agent.
OPTIONAL { ?agent foaf:givenName ?agentName }
?agent repr:hasRole ?role .
}
UNION
{
?material p-plan:isInputVarOf ?step .
?material prov:wasAttributedTo ?agent .
OPTIONAL {
?agent repr:name ?agentName .
?agent repr:hasRole ?role .
}
}
UNION
{
?material p-plan:isOutputVarOf ?step .
?material prov:wasAttributedTo ?agent .
OPTIONAL {
?agent repr:name ?agentName .
?agent repr:hasRole ?role .
}
}
}
Query 8:
Who created this experiment and when? Who modified it and when?
Select DISTINCT * WHERE
{
?experiment a :Experiment ;
:name ?Experiment ;
prov:wasAttributedTo ?Agent .
OPTIONAL {
?experiment prov:startedAtTime ?startedAtTime ;
prov:generatedAtTime ?generatedAtTime
}
}
Query 9:
Which are the publications or external resources that were referenced?
SELECT DISTINCT * WHERE
{
?experiment a repr:Experiment .
?step p-plan:isStepOfPlan ?experiment .
?publication p-plan:isOutputVarOf ?step ;
rdf:type repr:Publication ;
repr:doi ?publicationDOI .
OPTIONAL { ?publication repr:pmcid ?pmcid } .
OPTIONAL { ?publication repr:wasReleasedOn ?releaseDate } .
OPTIONAL { ?publication repr:pubmedid ?PubMed }
OPTIONAL { ?publication prov:wasAttributedTo ?author }
}
Query 10:
List all the experiments which uses growth protocol (EFO_0003789) and studies on "Homo sapiens" and resulted in phenotype "shorter prophase" which passed the quality control.
SELECT DISTINCT ?experiment ?image ?image_url WHERE
{
?experiment a repr:Experiment .
?step p-plan:isStepOfPlan ?experiment .
?image p-plan:isOutputVarOf ?step ;
a repr:Image .
?screen p-plan:isOutputVarOf ?step ;
a repr:Screen ;
p-plan:isVariableOfPlan ?protocol .
?protocol a repr:Protocol ;
repr:type ?type FILTER(?type="EFO_0003789") .
?image repr:reference ?organism .
?organism a repr:Organism ;
rdf:value ?organismvalue Filter(?organismvalue="Homo sapiens") .
?image repr:reference ?phenotype .
?phenotype a repr:Phenotype ;
rdf:value ?value Filter(?value="shorter prophase") .
?image repr:reference ?QualityControl .
?QualityControl a repr:QualityControl ;
rdf:value ?QualityControlValue FILTER(?QualityControlValue="pass") .
?image repr:isAvailableAt ?image_url
}